Inno Setup GIF 显示插件 GIFCtrl (V2.1 版本)


引用来自  test.iss 引用来自 test.iss
; -- test.iss --
; restools
; http://restools.hanzify.org
; gifctrl.dll 为一个用于 Inno Setup 的 13 KB 的 gif 显示插件,同样可以显示 BMP 和 JPEG。

; V2.1 可以同时显示 64 个 GIF 图片。解决插件加载后卸载时的延迟问题.

[Setup]
AppName=gifctrl
AppVerName=gifctrl Ver 2.1
DefaultDirName={pf}\gifctrl
DefaultGroupName=gifctrl
OutputDir=userdocs:Inno Setup Examples Output
SolidCompression=yes

[Files]
Source: "gifctrl.dll"; Flags: dontcopy solidbreak
Source: nsisinstall.gif; Flags: dontcopy solidbreak
Source: 0023.gif; Flags: dontcopy solidbreak
Source: "MyProg.exe"; DestDir: "{app}"
Source: "Readme.txt"; DestDir: "{app}"; Flags: isreadme

[Icons]
Name: "{group}\gifctrl"; Filename: "{app}\MyProg.exe"

[code]
const
  
HALIGN_CENTER = 0; //水平居中
  
HALIGN_LEFT = 1;   //水平靠左
  
HALIGN_RIGHT = 2;  //水平靠右

  
VALIGN_CENTER = 0; //垂直居中
  
VALIGN_TOP = 1;    //垂直靠上
  
VALIGN_BOTTOM = 2; //垂直靠下

  
FIT_NONE = 0;      //不适应窗口
  
FIT_WIDTH = 1;     //适应窗口宽度
  
FIT_HEIGHT = 2;    //适应窗口高度
  
FIT_BOTH = 3;      //适应窗口宽度和高度
  
  
CLR_INVALID = $FFFFFFFF; //自动取容器左上角的颜色作为底色,如果取色失败,用按钮颜色代替。

// 创建 Gif 窗口
function NewGifbWnd(hWndParent: HWND; X, Y, nWidth, nHeight: Integer): HWND; external 'newgifwnd@files:gifctrl.dll stdcall';

// 释放 Gif 窗口
function FreeGifWnd(hWndGif: HWND): Boolean; external 'freegifwnd@files:gifctrl.dll stdcall';

// 释放所有 Gif 窗口
function FreeAllGifWnd(): Boolean; external 'freeallgifwnd@files:gifctrl.dll stdcall';

// 设置 Gif 窗口的父窗口
function GifWndSetParent(hWndGif: HWND; hWndParent: HWND): Boolean; external 'gifwndsetparent@files:gifctrl.dll stdcall';

// 设置 Gif 窗口的位置大小
function GifWndSetBounds(hWndGif: HWND; X, Y, nWidth, nHeight: Integer): Boolean; external 'gifwndsetbounds@files:gifctrl.dll stdcall';

// 载入图片,并设置图片显示位置
function GifWndLoadFromFile(hWndGif: HWND; HAlign, VAlign: Integer; BGColor: DWord; Fit: integer; GifFileName: PChar): Boolean; external 'gifwndloadfromfile@files:gifctrl.dll stdcall';
// 第1 次载入需要指定图片文件“GifFileName”,然后在需要重新载入另外图片的时候重新指定另外的图片文件,重新调整 Align 位置时也需要调用此函数,
// 但是如果只是为了调整 Align 而不想重新载入一次 GifFileName 文件,只需要把 GifFileName 设置为空字符串就可以达到只调整位置,不重载文件。

var
  
GifPanel: TPanel;
  GIFHWND1, GIFHWND2: HWND;

function InitializeSetup(): Boolean;
begin
  
GIFHWND1 := 0;
  GIFHWND2 := 0;
  Result := True;
end;

procedure DeinitializeSetup();
begin
  
FreeAllGifWnd();
end;

procedure LblOnClick(Sender: TObject);
var
  
ErrorCode: Integer;
begin
  
ShellExec('open', 'http://restools.hanzify.org', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;

procedure InitializeWizard();
var
  
GifFileName: String;
  Lbl: TNewStaticText;
begin
  
ExtractTemporaryFile('nsisinstall.gif');
  ExtractTemporaryFile('0023.gif');

  GIFHWND1 := NewGifbWnd(WizardForm.InstallingPage.Handle, 0, WizardForm.PROGRESSGAUGE.Top + WizardForm.PROGRESSGAUGE.Height + SCaleY(5),
       WizardForm.InstallingPage.Width, WizardForm.InstallingPage.Height - (WizardForm.PROGRESSGAUGE.Top
       + WizardForm.PROGRESSGAUGE.Height + SCaleY(5)));
  GifWndLoadFromFile(GIFHWND1, HALIGN_CENTER, VALIGN_BOTTOM, CLR_INVALID, FIT_WIDTH, ExpandConstant('{tmp}\nsisinstall.gif'));

  // 创建一个网站 Logo 连接
  
GIFHWND2 := NewGifbWnd(WizardForm.Handle, ScaleX(30), WizardForm.Bevel.Top + ScaleY(8), 88, 31);
  GifWndLoadFromFile(GIFHWND2, HALIGN_CENTER, VALIGN_CENTER, CLR_INVALID, FIT_NONE, ExpandConstant('{tmp}\0023.gif'));
  Lbl := TNewStaticText.Create(WizardForm);
  Lbl.Parent := WizardForm;
  Lbl.AutoSize := False;
  Lbl.SetBounds(ScaleX(30), WizardForm.Bevel.Top + ScaleY(8), 88, 31);
  Lbl.OnClick := @LblOnClick;
  Lbl.Cursor := crHand;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if
CurPageID = wpInstalling then
  begin
    
MsgBox('暂停一下,看看效果。', mbInformation, MB_OK);
  end;
end;


点击下面连接下载例子。
http://restools.hanzify.org/inno/gifctrl/inno_gifctrl_v2.1.zip



评论: 30 | 引用: 0 | 查看次数: 29268
似水流年 [2016-10-28 10:15 PM]
新手问下你的文件是iss怎么直接运行,新手不懂,请指教
Eirc [2013-02-06 03:41 PM]
感謝您的回覆
及好用的工具^^
xin [2013-02-06 01:02 PM]
通常 EXE 或者 DLL 文件在资源管理器中显示属性页面中都有版本页面, 通常版本页面中都有列明相关版权人的信息.
你的意思是想把它用在商业方面么?
如果你只是使用的话, 绝没问题, 无论个人使用还是企业使用. 无任何使用上的限制.
Eric [2013-02-06 00:43 AM]
>保留 DLL 的版权信息即可
請問DLL 的版权信息為何?
如何取得?
xin [2013-02-05 01:20 PM]
引用来自 Eric 引用来自 Eric
請問如何正確引用 GIFCtrl  在產品中,
i.e Copyright, and License type and etc. ?

你的意思是?
免费的插件, 无任何限制. 无须作任何的版权声明, 保留 DLL 的版权信息即可.
Eric [2013-02-04 05:50 PM]
請問如何正確引用 GIFCtrl  在產品中,
i.e Copyright, and License type and etc. ?
xin [2011-05-18 12:53 AM]
加一个 Timer 控件进行时间倒数, 倒数完了就换图就可以了.
xlmldh [2011-05-18 02:01 AM]
那如何让程序在循环时间过后再继续执行呢,就像下面:

GIFHWND := NewGifbWnd(WizardForm.Handle, 95, 321, 88, 31);
GifWndLoadFromFile(GIFHWND, HALIGN_CENTER, VALIGN_CENTER, CLR_INVALID, FIT_BOTH, ExpandConstant('{tmp}\logo.gif'));
//如何延迟5秒再执行下面的代码
FreeGifWnd(GIFHWND);
xin [2011-05-16 07:45 PM]
应该不支持"循环次数", 好像没发现有什么特别需要的地方,如果你硬要它停下来, 你可以计算它循环需要的时间后, 隐藏它, 改为显示一个 BMP 就可以了.
xlmldh [2011-05-11 07:13 PM]
这个插件不支持gif图片本身的循环次数?
发表评论
昵 称:
密 码: 游客发言不需要密码.
验证码: 验证码
内 容:
选 项:
虽然发表评论不用注册,但是为了保护您的发言权,建议您注册帐号.
字数限制 5000 字 | UBB代码 开启 | [img]标签 关闭